VisibilityCalculator.VisibilityTimes(TimeSpan, TimeSpanArray, Array) Method

 Top 

Description

Detects start of visibility (AOS) and end of visibility (LOS) events.

 

Timing Precision Mode

This page describes functionality in nanosecond timing precision mode.

 

Note: This is an interval method. See the Interval Methods page for more information.

Note: This method has a state. See the Methods and Properties with State page for more information.

 

Method Signature

VisibilityCalculator.VisibilityTimes(

TimeSpan evaluationEpoch,

TimeSpanArray eventTimes,

Array eventTypes)

 

Arguments

evaluationEpoch

Description:

This epoch defines an end-point of the evaluation interval. FreeFlyer will determine whether any events have occurred between this epoch and the previous evaluationEpoch specified for this argument.

 

eventTimes

Description:

An Array to be filled with the detected event times.

 

eventTypes

Description:

An Array to be filled with the detected event types.

Event Type == 1 is start of visibility.

Event Type == 2 is end of visibility.

 

The FF_Preferences.IntervalEventReportingBehavior property controls whether the start of propagation is reported as an event. By default, if visibility starts before the beginning of the propagation span, FreeFlyer will label the start of the propagation as the start of visibility.

 

 

Return Value

Type:

number

 

Returns the number of detected event.

 

Syntax

myVariable1 = myVisibilityCalculator1.VisibilityTimes(myTimeSpan1, myTimeSpanArray1, myArray1);

 

Example 1

The example below shows how to compute the times when any of a set of three Sensors on a Spacecraft can see a particular GroundStation using the VisibilityCalculator.VisibilityTimes() method. The event times and types are stored in arrays, which are used to create a custom-formatted data report. Event Type = 1 means start of visibility; Event Type = 2 means end of visibility.

 

// Create Objects

Variable i;

Variable numEvents;

Array EventTypes[0];

TimeSpanArray EventTimes[0];

StringArray EventTypeLabels = {"", "Start of visibility", "End of visibility"};

GroundStation GroundStation1;

 

Spacecraft Spacecraft1;

Spacecraft1.AddSensor("Sensor1");

Spacecraft1.AddSensor("Sensor2");

Spacecraft1.AddSensor("Sensor3");

 

// Create the VisibilityCalculator and Segments

VisibilityCalculator VisibilityCalc;

VisibilityCalc.VisibilityRequirement = 1;  // Any

 

VisibilityCalc.AddSegment("Sensor1-to-GS");

VisibilityCalc.AddSegment("Sensor2-to-GS");

VisibilityCalc.AddSegment("Sensor3-to-GS");

 

// Set up the Segments

For i = 0 to VisibilityCalc.Segments.Count-1;

 

          Spacecraft1.Sensors[i].BoresightAngles[2] = i*20;

 

          VisibilityCalc.Segments[i].SetObserver(Spacecraft1.Sensors[i]);

          VisibilityCalc.Segments[i].SetTarget(GroundStation1);

 

End;

 

// Propagate and determine visibility times when *any* of the Sensors can see the GroundStation

While (Spacecraft1.ElapsedTime < TIMESPAN(0.5 days));

 

          numEvents = VisibilityCalc.VisibilityTimes(Spacecraft1.Epoch, EventTimes, EventTypes);

 

          For i = 0 to numEvents-1 step 1;                        

                      Report EventTypeLabels[EventTypes[i]], EventTimes[i].ConvertToCalendarDate();

          End;

 

          Step Spacecraft1;

 

End;

 

Output excerpt:

 

EventTypeLabels[EventTypes[i]]

EventTimes[i].ConvertToCalendarDate

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

Jan 01 2020 02:05:02.197265625

Jan 01 2020 02:17:37.690429687

Jan 01 2020 03:39:46.303710937

Jan 01 2020 04:27:19.819335937

Jan 01 2020 05:17:30.219726562

Jan 01 2020 06:15:50.390625000

Jan 01 2020 06:55:30.615234375

Jan 01 2020 07:55:38.671875000

Jan 01 2020 08:33:22.734375000

Jan 01 2020 09:24:55.825195312

Jan 01 2020 10:10:39.038085937

Jan 01 2020 10:52:56.147460937

Jan 01 2020 11:46:06.503906250

 

Example 2

The example below shows how to compute the times when a GroundStation can any of the following targets: the Moon, the Sun, or a particular Spacecraft. The VisibilityCalculator.VisibilityTimes() method is used to store the event times and types in arrays, which are used to create a custom-formatted data report. Event Type = 1 means start of visibility; Event Type = 2 means end of visibility.

 

// Create Objects

GroundStation GroundStation1;

Spacecraft Spacecraft1;

Variable i;

Variable numEvents;

Array EventTypes[0];

TimeSpanArray EventTimes[0];

StringArray EventTypeLabels = {"", "Start of visibility", "End of visibility"};

 

// Create the VisibilityCalculator and Segments

VisibilityCalculator VisibilityCalc;

VisibilityCalc.VisibilityRequirement = 1;  // Any

 

VisibilityCalc.AddSegment("GS-to-Moon");

VisibilityCalc.AddSegment("GS-to-Sun");

VisibilityCalc.AddSegment("GS-to-SC");

 

// Set up the Segments

For i = 0 to VisibilityCalc.Segments.Count-1;

          VisibilityCalc.Segments[i].SetObserver(GroundStation1);

End;

 

VisibilityCalc.GetSegmentByLabel("GS-to-Moon").SetTarget(Moon);

VisibilityCalc.GetSegmentByLabel("GS-to-Sun").SetTarget(Sun);

VisibilityCalc.GetSegmentByLabel("GS-to-SC").SetTarget(Spacecraft1);

 

// Propagate and determine visibility times when *any* of the Sensors can see the GroundStation

While (Spacecraft1.ElapsedTime < TIMESPAN(0.5 days));

 

          numEvents = VisibilityCalc.VisibilityTimes(Spacecraft1.Epoch, EventTimes, EventTypes);

 

          For i = 0 to numEvents-1 step 1;        

                      Report EventTypeLabels[EventTypes[i]], EventTimes[i].ConvertToCalendarDate();

          End;

 

          Step Spacecraft1;

 

End;

 

Output excerpt:

 

EventTypeLabels[EventTypes[i]]

EventTimes[i].ConvertToCalendarDate()

Start of visibility

End of visibility

Start of visibility

End of visibility

Start of visibility

End of visibility

Jan 01 2020 00:00:00.000000000

Jan 01 2020 02:51:02.915039062

Jan 01 2020 06:19:55.825195312

Jan 01 2020 06:27:47.944335937

Jan 01 2020 07:57:38.129882812

Jan 01 2020 08:05:20.727539062

 

See also

VisibilityCalculator Object

Coverage and Contact Analysis Guide

Visibility Calculators Guide